實(shí)戰(zhàn):sqlserver2008擴(kuò)展事件-XML轉(zhuǎn)換為標(biāo)準(zhǔn)的table格式_MySQL

--如果已經(jīng)存在Event Session刪除 
 
IF EXISTS (SELECT * FROM sys.server_event_sessions WHERE name='MonitorLongQuery') 
DROP EVENT SESSION MonitorLongQuery ON SERVER 
GO 
 
--創(chuàng)建Extended Event session 
 
CREATE EVENT SESSION MonitorLongQuery ON SERVER 
--增加Event(SQL完成事件) 
ADD EVENT sqlserver.sql_statement_completed 
( 
--指定收集的Event信息 
ACTION 
( 
sqlserver.database_id, 
sqlserver.session_id, 
sqlserver.username, 
sqlserver.client_hostname, 
sqlserver.sql_text, 
sqlserver.tsql_stack 
) 
 
--Filter信息（CPU超過或者整個(gè)運(yùn)行時(shí)間超過10S） 
 
WHERE sqlserver.sql_statement_completed.cpu> 10000 
OR sqlserver.sql_statement_completed.duration> 10000 
) 
--指定收集的Event信息儲(chǔ)存位置（可以存儲(chǔ)到內(nèi)存也可以到文件） 
ADD TARGET package0.asynchronous_file_target 
( 
SET FILENAME = N's:\monitor\LogQuery.xet', 
METADATAFILE = 'S:\monitor\LongQuery.xem' 
) 
GO 
 
SELECT sessions.name AS SessionName,sevents.package as PackageName, 
sevents.name AS EventName, 
sevents.predicate, sactions.name AS ActionName, stargets.name AS TargetName 
FROM sys.server_event_sessions sessions 
INNER JOIN sys.server_event_session_events sevents 
ON sessions.event_session_id= sevents.event_session_id 
INNER JOIN sys.server_event_session_actions sactions 
ON sessions.event_session_id= sactions.event_session_id 
INNER JOIN sys.server_event_session_targets stargets 
ON sessions.event_session_id= stargets.event_session_id 
WHERE sessions.name='MonitorLongQuery' 
GO 
 
 
--啟動(dòng)Event Session捕獲數(shù)據(jù) 
 
ALTER EVENT SESSION MonitorLongQuery 
ON SERVER STATE = START 
GO 
 
--查詢 
 
SELECT CAST(event_data AS XML) event_data,* 
FROM sys.fn_xe_file_target_read_file 
 
('s:\monitor\LogQuery_0_129954478780290000.xet', 
 's:\monitor\LongQuery_0_129954478780330000.xem',NULL,NULL) 
go 
 
 
 
-停掉Event Session 
 
ALTER EVENT SESSION MonitorLongQuery 
 
ON SERVER STATE = STOP 
 
GO 
 
 
 
--刪除Event Session 
 
IF EXISTS(SELECT * FROM sys.server_event_sessions WHERE name='MonitorLongQuery') 
 
DROP EVENT SESSION MonitorLongQuery ON SERVER 
 
GO 


------------將XML轉(zhuǎn)換為常規(guī)的表格式 
IF EXISTS ( SELECT *
 FROM tempdb.dbo.sysobjects
 WHERE id = OBJECT_ID(N'tempdb..#MyData')
 AND type = 'U' ) 
 DROP TABLE #MyData
go

CREATE TABLE #MyData
 (
 database_id INT NOT NULL ,
 username NVARCHAR(100) NOT NULL,
 client_hostname NVARCHAR(100) NOT NULL,
 sql_text NVARCHAR(MAX) NOT NULL ,
 cpu INT NOT NULL
 )
go


DECLARE @xmlData XML
DECLARE @xmlString NVARCHAR(MAX)
DECLARE @database_id INT
DECLARE @username NVARCHAR(100)
DECLARE @client_hostname NVARCHAR(100)
DECLARE @sql_text NVARCHAR(MAX)
DECLARE @cpu INT

DECLARE myCur CURSOR READ_ONLY
FOR
SELECT TOP 200 event_data --CAST(event_data AS XML)
FROM sys.fn_xe_file_target_read_file

('s:\monitor\LogQuery_0_130638808366940000.xet',
 's:\monitor\LongQuery_0_130638808366940000.xem',NULL,NULL) 

OPEN myCur

FETCH NEXT FROM myCur INTO @xmlString

WHILE @@FETCH_STATUS = 0 

BEGIN
	 BEGIN TRY
	 SET @xmlData = CAST(@xmlString AS XML)
	 --set @cpu = 0
	 --獲取cpu	 
	SET @cpu = @xmlData.query('//data[@name="cpu"]/value').value('(value)[1]',
	 'INT')
	 
	 --獲取database_id
	SET @database_id = @xmlData.query('//action[@name="database_id"]/value').value('(value)[1]',
	 'INT')
	--獲取username	 
 SET @username = @xmlData.query('//action[@name="username"]/value').value('(value)[1]',
	 'NVARCHAR(100)')
	--獲取hostname	 
 SET @client_hostname = @xmlData.query('//action[@name="client_hostname"]/value').value('(value)[1]',
	 'NVARCHAR(100)')
	 
	--獲取sql_text
	SET @sql_text = @xmlData.query('//action[@name="sql_text"]/value').value('(value)[1]',
	 'NVARCHAR(MAX)')
	

	--開始插入數(shù)據(jù)
	INSERT #MyData
	( database_id, 
	 sql_text, 
	 username,
	 client_hostname,
	 cpu )
	VALUES ( @database_id, -- database_id - int
	 @sql_text, -- sql_text - nvarchar(max)
	 @username,
	 @client_hostname,
	 @cpu
	 )
	 END TRY
	 BEGIN CATCH
	 END CATCH
	
	
 FETCH NEXT FROM myCur INTO @xmlString
END
CLOSE myCur
DEALLOCATE myCur



SELECT b.name,a.username,a.client_hostname,a.sql_text,a.cpu FROM #MyData AS a
inner join sys.databases as b
on a.database_id=b.database_id
order by a.cpu desc
go